prologues:=3;
filenametemplate "%j.mps";
verbatimtex
%&latex
\documentclass{minimal}
\begin{document}
etex
beginfig(0);
% ----------------------------
% A magnifying glass
% ----------------------------
  z.CENT.MGLASS = (0, -2in);
  d.MGLASS = 1in;
  r.MGLASS = .5 d.MGLASS;
  fill fullcircle scaled d.MGLASS shifted z.CENT.MGLASS withcolor white;
  pickup pencircle scaled 0.05 r.MGLASS;
  draw fullcircle scaled d.MGLASS shifted z.CENT.MGLASS;
  draw fullcircle scaled 0.92d.MGLASS shifted z.CENT.MGLASS;
  z.MGLASS0 = z.CENT.MGLASS + (dir 15)*(0.5 r.MGLASS);
  z.MGLASS0.5 = z.CENT.MGLASS + (dir 30)*(0.5 r.MGLASS);
  z.MGLASS1 = z.CENT.MGLASS + (dir 45)*(0.5 r.MGLASS);
  z.MGLASS2 = z.CENT.MGLASS + (dir 15)*(0.6 r.MGLASS);
  z.MGLASS2.5 = z.CENT.MGLASS + (dir 30)*(0.6 r.MGLASS);
  z.MGLASS3 = z.CENT.MGLASS + (dir 45)*(0.6 r.MGLASS);
  draw z.MGLASS0{-sind 30, cosd 15}.. {-sind 30, cosd 30}z.MGLASS0.5 .. {-sind 45, cosd 45}z.MGLASS1;
  draw z.MGLASS2{-sind 30, cosd 15}.. {-sind 30, cosd 30}z.MGLASS2.5 .. {-sind 45, cosd 45}z.MGLASS3;
  z.MGLASS4 = z.CENT.MGLASS + (dir 225)*(1.2 r.MGLASS);
  z.MGLASS5 = z.CENT.MGLASS + (dir 225)*(3.0 r.MGLASS);
  z.MGLASS6 = z.MGLASS4 + (dir 315)*(0.2 r.MGLASS);
  z.MGLASS7 = z.MGLASS4 + (dir  45)*(0.2 r.MGLASS);
  z.MGLASS8 = z.MGLASS4 + (dir 135)*(0.2 r.MGLASS);
  z.MGLASS9 = z.MGLASS5 + (dir 135)*(0.2 r.MGLASS);
  z.MGLASS10 = z.MGLASS5 + (dir 225)*(0.2 r.MGLASS);
  z.MGLASS11 = z.MGLASS5 + (dir 315)*(0.2 r.MGLASS);
  draw z.MGLASS6{dir 45}..z.MGLASS7{dir 135}..{dir 225}z.MGLASS8
    --z.MGLASS9{dir 225}..{dir 315}z.MGLASS10..{dir 45}z.MGLASS11
    --cycle;
  fill z.MGLASS4--z.MGLASS6--z.MGLASS11--z.MGLASS5--cycle;
  draw z.MGLASS6--z.MGLASS8;
  draw z.MGLASS9--z.MGLASS11;
endfig;
end