#declare degr = pi/180;

#declare cam_theta = 15*degr;
#declare cam_phi = 24*degr;
#declare cam_distance = 2.8;

#declare plane_thickness = 0.005;
#declare curve_thickness = 0.00667;

background { rgb <0.7,0.7,0.7> }

camera {
  location <cos(cam_phi)*cos(cam_theta),sin(cam_phi),cos(cam_phi)*sin(cam_theta)>*cam_distance
  look_at <0,0,0>
}

light_source { <1,3, 1> rgb<1,1,1> }
light_source { <1,3, 0> rgb<1,1,1> }
light_source { <1,3,-1> rgb<1,1,1> }

light_source { <0,3, 1> rgb<1,1,1> }
light_source { <0,3, 0> rgb<1,1,1> }
light_source { <0,3,-1> rgb<1,1,1> }

light_source { <-1,3, 1> rgb<1,1,1> }
light_source { <-1,3, 0> rgb<1,1,1> }
light_source { <-1,3,-1> rgb<1,1,1> }

// XZ plane 
intersection {
  plane { <0,1,0>,plane_thickness/2 }
  plane { <0,-1,0>,plane_thickness/2 }
  box { <-1,-1,-1>,<1,1,1> }
  pigment { rgbf <1,0.5,1,0.9> }
}
// XY plane 
intersection {
  plane { <0,0,1>,plane_thickness/2 }
  plane { <0,0,-1>,plane_thickness/2 }
  box { <-1,-1,-1>,<1,1,1> }
  pigment { rgbf <1,1,0.5,0.9> }
}
// YZ plane 
intersection {
  plane { <1,0,0>,plane_thickness/2 }
  plane { <-1,0,0>,plane_thickness/2 }
  box { <-1,-1,-1>,<1,1,1> }
  pigment { rgbf <0.5,1,1,0.9> }
}

// the curve ...
#local n = 0;
#while (n <= 200)
 #local p = (n-100)/100;
 #local x0 = p;
 #local z0 = p*p/2;
 #local y0 = p*p*p/3;
 #if (n > 0) // Curve is drawn by connecting very short cylinders
  cylinder { 
   <x0,y0,z0>,<x1,y1,z1>,curve_thickness
   pigment { rgb <0.8,0.5,0.5> }
  }
 #end // of #if
 #local x1 = x0;
 #local y1 = y0;
 #local z1 = z0;
 #local n = n + 1;
#end // of #while